dnl Autoconf file for ETL

AC_PREREQ(2.50)
AC_INIT(src/template/template.c)

AC_CONFIG_AUX_DIR(build)

sinclude(libtool.m4)

AC_PREFIX_DEFAULT(/usr/local/etl)

AC_CANONICAL_SYSTEM

orig_prefix="$prefix"

AC_PROG_CC
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LIBTOOL

echo $ac_n "Configuring ETL...${nl}"

dnl Absolute source/build directory
abs_srcdir=`(cd $srcdir && pwd)`
abs_builddir=`pwd`

my_top_builddir=`pwd`

AC_SUBST(my_top_builddir)

mkdir_p=$abs_srcdir/build/mkdir.sh

AC_SUBST(mkdir_p)

dnl get our version information
get_version="$abs_srcdir/build/get-version.sh"
version_hdr="$abs_srcdir/include/etl_version.h"
ETL_MAJOR_VERSION="`$get_version major $version_hdr ETL`"
ETL_DOTTED_VERSION="`$get_version all $version_hdr ETL`"

dnl we want a special includedir so that multiple different major versions
dnl of etl can be installed alongside each other.
includedir="${prefix}/include/etl-${ETL_MAJOR_VERSION}"

AC_SUBST(ETL_MAJOR_VERSION)
AC_SUBST(ETL_DOTTED_VERSION)

AC_SUBST(ETL_BUILD_SRCLIB_DIRS)
AC_SUBST(ETL_CLEAN_SRCLIB_DIRS)

case "$host" in
  *-linux-*)
    CPPFLAGS="$CPPFLAGS -D_REENTRANT -D_GNU_SOURCE"
    ;;
esac

AC_SUBST(CPPFLAGS)

AC_CONFIG_FILES([Makefile])
AC_CONFIG_FILES([etl.pc])

AC_ARG_WITH(pkg-config,
AC_HELP_STRING([--with-pkg-config=PATH],
               [Specifiy the path to the pkg-config command]),
[
  PKGCONFIG=$withval
])

if test "$PKGCONFIG" = "yes"; then
  PKGCONFIG=""
fi

if test "x$PKGCONFIG" = "x"; then
  AC_PATH_PROG(PKGCONFIG, pkg-config, none)
fi

if test "$PKGCONFIG" != "none"; then
  PKGCONFIG_FILE="etl-${ETL_MAJOR_VERSION}.pc"
else
  PKGCONFIG_FILE=""
fi

AC_SUBST(PKGCONFIG_DIR)
AC_SUBST(PKGCONFIG_FILE)

AC_OUTPUT